.include "c:\avrtools\appnotes\2313def.inc"

;------ Commands ---------------------------------------------

.equ cmdClearDisplay =  0x80    ;To distingish these commands from
.equ cmdGotoLine1 =     0x81    ;standard ASCII, the MSB is set.
.equ cmdGotoLine2 =     0x82
.equ cmdGotoLine3 =     0x83
.equ cmdGotoLine4 =     0x84
.equ cmdCursorLeft =    0x85
.equ cmdCursorRight =   0x86
.equ cmdDisplayOff =    0x87
.equ cmdDisplayOn =     0x88
.equ cmdCursorOn =      0x89
.equ cmdCursorOff =     0x8A
.equ cmdBlinkOn =       0x8B
.equ cmdBlinkOff =      0x8C
.equ cmdWakeup =        0x8D

;------ PortB Defines ----------------------------------------
.equ db0        = 0             ;display data 0
.equ db1        = 1             ;display data 1
.equ db2        = 2             ;display data 2
.equ db3        = 3             ;display data 3
.equ db4        = 4             ;display data 4
.equ db5        = 5             ;display data 5
.equ db6        = 6             ;display data 6
.equ db7        = 7             ;display data 7
;------ PortD Defines ----------------------------------------
.equ rs         = 2             ;register select
.equ rw         = 3             ;read/write select
.equ ce         = 4             ;display enable

;------ Macros for Port control -----------------------------
.macro  CE_HI
                sbi portd,ce
.endm
.macro  CE_LOW
                cbi portd,ce
.endm
.macro  RS_HI
                sbi portd,RS
.endm
.macro  RS_LOW
                cbi portd,RS
.endm
.macro  RW_HI
                sbi portd,RW
.endm
.macro  RW_LOW
                cbi portd,RW
.endm

;------ Display Constants -----------------------------------

.equ    c_Clr           = 0x01          ;clear display
.equ    c_CursorLeft    = 0x10          ;move cursor left
.equ    c_CursorRight   = 0x14          ;move cursor right
.equ    c_Goto          = 0x80          ;data ram control
.equ    c_Line2         = 0x40          ;start address of line 2
.equ    c_Line3         = 0x14          ;start address of line 3
.equ    c_Line4         = 0x54          ;start address of line 4

.equ    f_Set           = 0x30          ;Function Commands
.equ    f_1line         = 0x00          ;1 line mode
.equ    f_2line         = 0x08          ;2 line mode
.equ    f_8font         = 0x00          ;5x8 font
.equ    f_11font        = 0x04          ;5x11 font

.equ    d_Set           = 0x08          ;Display Control
.equ    d_DisplayOn     = 0x04          ;Display on
.equ    d_DisplayOff    = 0x00          ;Display off
.equ    d_CursorOn      = 0x02          ;Cursor on
.equ    d_CursorOff     = 0x00          ;Cursor off
.equ    d_BlinkOn       = 0x01          ;Blink on
.equ    d_BlinkOff      = 0x00          ;Blink off

.equ    e_Set           = 0x04          ;Entry mode control
.equ    e_CursorRight   = 0x02          ;cursor moves right
.equ    e_CursorLeft    = 0x00          ;cursor moves left
.equ    e_NoShift       = 0x00          ;cursor doesn't shift
.equ    e_Shift         = 0x01          ;cursor shifts

;------ Flag Bits ---------------------------------------

.equ    Tick            = 0             ;Timer Tick bit

;------ Register Defines --------------------------------

.def    lpmr0 =         r0              ;used with lpm instruction
.def    ISRtimer =      r1              ;timer ISR
.def    ISRUart =       r2              ;uart rcx ISR
.def    temp =          r3              ;temp register used in uart ISR
.def    Acc =           r16             ;accumulator
.def    Flags =         r17             ;Flag bits
.def    MyLoop =        r18             ;loop counter
.def    Command =       r19             ;command from uart
.def    Head =          r26             ;X register is head pointer
.def    Tail =          r28             ;Y register is tail pointer

;------ Memory Defines ----------------------------------

.equ    Buffer =        0x60            ;start of receiver buffer
.equ    BufEnd =        0xa0            ;end of receiver buffer

;------ Code Start --------------------------------------
        .cseg                           ;start code segment
        .org 0
        rjmp    Start                   ;reset vector
        reti                            ;irq0
        reti                            ;irq1
        reti                            ;timer1 capture
        rjmp    Timer                   ;timer1 compare
        reti                            ;timer1 overflow
        reti                            ;timer0 overflow
        rjmp    uartrx                  ;uart receive
        reti                            ;udr empty
        reti                            ;tx complete
        reti                            ;analog compare

;****************************************************************
;       Timer - Timer Interrupt Service Routine                 *
;               Entry occurs every 1ms                          *
;****************************************************************
Timer:
        in      ISRtimer,sreg           ;save status register
        sbr     Flags,1<<Tick           ;set the tick flag
        out     sreg,ISRtimer           ;restore status register
        reti

;****************************************************************
;       UartRx - Here when a command received on the uart       *
;****************************************************************
UartRx:
        in      ISRUart,sreg            ;save status register
        in      temp,udr                ;get the command
        st      x+,temp                 ;store the command
        cpi     xl,BufEnd               ;test for end of buffer
        brne    UR1                     ;jump if ok
        ldi     xl,Buffer               ;reset pointer
UR1:
        out     sreg,ISRUart            ;restore status register
        reti

;****************************************************************
;       Display Commands                                        *
;       These token commands come from the serial port and tell *
;       this micro what to do.  The following command table     *
;       is used with the icall command to jump to the actual    *
;       command routine.                                        *
;****************************************************************
CommandTable:
        rjmp    ClearDisplay            ;0x80
        rjmp    GotoLine1               ;0x81
        rjmp    GotoLine2               ;0x82
        rjmp    GotoLine3               ;0x83
        rjmp    GotoLine4               ;0x84
        rjmp    CursorLeft              ;0x85
        rjmp    CursorRight             ;0x86
        rjmp    DisplayOff              ;0x87
        rjmp    DisplayOn               ;0x88
        rjmp    CursorOn                ;0x89
        rjmp    CursorOff               ;0x8A
        rjmp    BlinkOn                 ;0x8B
        rjmp    BlinkOff                ;0x8C
        rjmp    Wakeup                  ;0x8D

;****************************************************************
;       Start - Start of code                                   *
;****************************************************************
Start:
        ldi     r16,0xff                ;portb 7-0 are outputs
        out     ddrb,r16
        ldi     r16,0xff                ;portd 7-0 are outputs
        out     ddrd,r16

        ldi     r16,0xff
        out     portb,r16
        out     portd,r16
        CE_LOW
        RS_LOW
        RW_LOW

        ldi     r16,low(RAMEND)         ;load the stack pointer
        out     SPL,r16

        ldi     r16,0x00
        out     tccr1a,r16              ;disable PWM mode
        ldi     r16,0x09
        out     tccr1b,r16              ;clear timer on compare/no prescale
        ldi     r16,0x1c
        out     ocr1ah,r16              ;load output compare register
        ldi     r16,0xcc                ;1ccc = 1ms on compare
        out     ocr1al,r16
        clr     Flags                   ;turn off all flags

        ldi     r16,0x40
        out     timsk,r16               ;enable timer1 compare match interrupt

        ldi     r16,1
        out     ubrr,r16                ;115.2 kb baudrate
        ldi     r16,(1<<rxen)|(1<<rxcie)|(1<<txen)
        out     ucr,r16                 ;enable uart receive interrupt
        sei                             ;enable interrupts

        in      r16,udr                 ;flush uart
        ldi     Head,Buffer             ;point to begining of buffer
        ldi     Tail,Buffer             ;point to begining of buffer
        clr     xh                      ;clear the upper part of the pointer
        clr     yh                      ;clear the upper part of the pointer

        rcall   InitDisplay             ;start display

        ldi     r16,d_Set | d_DisplayOn | d_CursorOff | d_BlinkOff
        rcall   DisplayCmd
        rcall   DisplayRom
        .db     "Display Interface",0
        rcall   GotoLine2
        rcall   DisplayRom
        .db     "Version 1.1",0

MainLoop:
        cpse    head,tail               ;are the pointers equal?
        rjmp    ML1                     ;jump if a command is available
        rjmp    MainLoop                ;loop waiting for a command
ML1:
        ld      Command,y+              ;get the command
        cpi     yl,BufEnd               ;has pointer reached end of buffer?
        brne    ML2                     ;jump if ok
        ldi     yl,Buffer               ;reset pointer
ML2:
        sbrs    Command,7               ;is it ASCII or a command?
        rjmp    SendASCII               ;jump if it's ASCII

        cpi     Command,0x8e            ;verify we have a valid command
        brsh    MainLoop                ;jump if illegal command

        andi    Command,0x0f            ;mask off unused bits
        ldi     zl,low(CommandTable)    ;z register points to table
        ldi     zh,high(CommandTable)
        add     zl,Command              ;add offset to table
        brcc    ML3                     ;jump if no carry
        inc     zh                      ;add carry to zh
ML3:
        icall                           ;call the routine based on the command offset
        rjmp    MainLoop

SendASCII:
        mov     r16,Command
        rcall   DisplayChar             ;send ASCII right to the display
        rjmp    MainLoop                ;need to handle invalid command

ClearDisplay:
        ldi     r16,c_Clr
        rjmp    DisplayCmd

GotoLine1:
        ldi     r16,c_Goto
        rjmp    DisplayCmd

GotoLine2:
        ldi     r16,c_Goto + c_Line2
        rjmp    DisplayCmd

GotoLine3:
        ldi     r16,c_Goto + c_Line3
        rjmp    DisplayCmd

GotoLine4:
        ldi     r16,c_Goto + c_Line4
        rjmp    DisplayCmd

CursorLeft:
        ldi     r16,e_Set | e_CursorLeft
        rjmp    DisplayCmd

CursorRight:
        ldi     r16,e_Set | e_CursorRight
        rjmp    DisplayCmd

DisplayOff:
        ldi     r16,d_Set | d_DisplayOff
        rjmp    DisplayCmd

DisplayOn:
        ldi     r16,d_Set | d_DisplayOn
        rjmp    DisplayCmd

CursorOn:
        ldi     r16,d_Set | d_CursorOn | d_DisplayOn
        rjmp    DisplayCmd

CursorOff:
        ldi     r16,d_Set | d_CursorOff | d_DisplayOn
        rjmp    DisplayCmd

BlinkOn:
        ldi     r16,d_Set | d_BlinkOn | d_DisplayOn
        rjmp    DisplayCmd

BlinkOff:
        ldi     r16,d_Set | d_BlinkOff | d_DisplayOn
        rjmp    DisplayCmd

Wakeup:                                 ;init the display and send back an ACK
        ret

;****************************************************************
;       Busy - Read the display and wait for busy flag to clear *
;****************************************************************
Busy:
        ldi     r16,0x00                ;switch portb to inputs
        out     ddrb,r16
Busy1:
        RW_HI
        nop
        CE_HI                           ;read the display
        nop
        nop
        in      r16,pinb                ;read the display status
        CE_LOW
        sbrc    r16,7                   ;test the busy bit
        rjmp    Busy1                   ;loop till not busy

        RW_LOW
        ldi     r16,0xff                ;switch portb back to outputs
        out     ddrb,r16
        ret

;****************************************************************
;       DisplayByte - Displays r16 as a hex byte                *
;****************************************************************
DisplayByte:
        push    r16                     ;save data
        swap    r16
        andi    r16,0xf
        cpi     r16,0x0A
        brlo    Dbyte1
        subi    r16,-0x37               ;convert to ASCII
        rjmp    Dbyte2
Dbyte1:
        subi    r16,-0x30               ;convert to ASCII
Dbyte2:
        rcall   DisplayChar             ;display the data
        pop     r16                     ;restore data
        andi    r16,0xf
        cpi     r16,0x0A
        brlo    Dbyte3
        subi    r16,-0x37               ;convert to ASCII
        rjmp    Dbyte4
Dbyte3:
        subi    r16,-0x30               ;convert to ASCII
Dbyte4:
        rjmp    DisplayChar             ;display the data

;****************************************************************
;       DisplayCmd - Sends command in R16 to display module     *
;****************************************************************
DisplayCmd:
        out     portb,r16               ;drive port outputs
        CE_HI                           ;strobe display enable
        nop
        CE_LOW
        rjmp    Busy                    ;check display busy flag

;****************************************************************
;       DisplayChar - Sends character in R16 to display module  *
;****************************************************************
DisplayChar:
        RS_HI
        out     portb,r16               ;drive port
        CE_HI                           ;strobe display enable
        nop
        CE_LOW
        RS_LOW
        rjmp    Busy                    ;check display busy flag

;****************************************************************
;       InitDisplay - Startup the display                       *
;****************************************************************
InitDisplay:
        ldi     MyLoop,3                ;setup loop counter
InitDisp1:
        ldi     r16,100
        rcall   Delay                   ;wait 16ms
        ldi     r16,0x30
        rcall   DisplayCmd              ;8-bit mode
        dec     MyLoop                  ;decrement loop counter
        brne    InitDisp1               ;loop 3 times

        ldi     r16, f_Set | f_2line    ;2 line mode
        rcall   DisplayCmd
        ldi     r16, d_Set | d_DisplayOn | d_CursorOff
        rcall   DisplayCmd
        ldi     r16, e_Set | e_CursorRight | e_NoShift
        rcall   DisplayCmd
        ldi     r16, c_Clr
        rjmp    DisplayCmd              ;clear display and home cursor

;****************************************************************
;       Delay - Delays R16 milliseconds                         *
;****************************************************************
Delay:
        cbr     Flags,1<<Tick           ;reset tick flag
Delay1:
        sbrs    Flags,Tick              ;wait till timer interrupt sets Tick flag
        rjmp    Delay1                  ;loop till interrupt occurs
        dec     r16                     ;decrement counter
        brne    Delay                   ;loop until counter = 0
        ret

;****************************************************************
;       DisplayRom - Display a string stored in rom             *
;****************************************************************
DisplayRom:
        pop     zh
        pop     zl                      ;move stack pointer to Z register
        lsl     zl
        rol     zh                      ;shift Z register over

DR1:    lpm                             ;load character from rom
        mov     r16,r0
        cpi     r16,0
        breq    Rdone                   ;jump when EOM
        rcall   DisplayChar             ;display data
        adiw    zl,1                    ;inc Z register
        rjmp    DR1
Rdone:  lsr     zh                      ;restore the stack
        ror     zl
        adiw    zl,1                    ;point to next opcode after message
        push    zl                      ;push this location onto the stack
        push    zh
        ret